Cum se utilizează datele şi orele în Excel?

Excel stochează toate datele ca numere întregi şi toate orele ca fracţii zecimale. Prin acest sistem, Excel poate aduna, scădea sau compara date şi ore la fel ca orice alte numere, iar toate datele sunt procesate prin acest sistem.

În acest sistem, numărul de serie 1 reprezintă 1/1/1900 12:00:00 a.m. Orele sunt stocate sub formă de numere zecimale cuprinse între ,0 şi ,99999, unde ,0 este 00:00:00 şi ,99999 este 23:59:59. Numerele întregi ale datelor şi fracţiile zecimale ale orei pot fi combinate pentru a obţine numere care au o parte cu un număr între şi o parte cu o zecimală. De exemplu, numărul 32331,06 reprezintă data şi ora 7/7/1988 1:26:24 a.m.

Pentru a vă ajuta să efectuaţi calcule complexe cu date şi ore, Excel are multe funcţii încorporate pentru dată şi oră.

Funcţiile TODAY() şi NOW()

Funcţia TODAY generează numărul de serie al datei de azi în funcţie de ceasul sistemului dvs. şi nu include ora. Funcţia NOW generează numărul de serie al datei de azi în funcţie de şi include ora.

Cum se sortează datele în funcţie de numărul de serie

În Excel, datele se sortează în funcţie de numărul de serie al datei, în locul numărului afişat. Prin urmare, atunci când sortaţi datele în Excel, este posibil să nu obţineţi rezultatele prevăzute.

De exemplu, dacă sortaţi o serie de date afişate în formatul datei llll (astfel încât se afişează numai luna), lunile nu sunt sortate în ordine alfabetică. În schimb, sortarea datelor se face în funcţie de numărul de seria al datei subadiacent.

Cum se compară datele în funcţie de numărul de serie

Deoarece numerele de serie se utilizează şi la compararea datelor şi orelor, rezultatele efective pot să difere faţă de cele prevăzute (în funcţie de valorile afişate).

De exemplu, dacă utilizaţi funcţia NOW pentru a compara o dată cu data curentă, ca în formula

   =IF(NOW()=DATEVALUE("10/1/92"),TRUE,FALSE)

rezultatul formulei este FALSE (FALS), chiar dacă data curentă este 10/1/92; rezultatul este TRUE (ADEVĂRAT) numai dacă data este 10/1/92 12:00:00 a.m. În cazul în care comparaţi două

date într-o formulă şi nu trebuie să aveţi ora inclusă în rezultat, puteţi ocoli acest comportament utilizând în loc funcţia TODAY:

   =IF(TODAY()=DATEVALUE("10/1/92"),TRUE,FALSE)

Cum se lucrează cu formulele de date

Cum se găseşte numărul de zile între ziua de astăzi şi o dată viitoare

Pentru a găsi numărul de zile între momentul actual şi o dată viitoare, folosiţi formula următoare

   ="mm/dd/yy"-NOW()

unde “mm/dd/yy” este data viitoare. Utilizați formatul General pentru a formata celula care conţine formula.

Cum se găseşte numărul de zile, luni şi ani între două date

Pentru a calcula numărul de zile, luni şi ani între două date, unde datele de început şi de sfârşit sunt introduse în celulele A1 şi respectiv A2, urmaţi aceşti paşi:

1. Creaţi un registru de lucru nou.
2. Faceţi clic pe Registru de lucru necompletat
3. Tastaţi următoarele date în registrul de lucru:

A1:03/25/94 A2: 05/01/98
Introduceţi următoarea formulă în celula D1:
 =YEAR(A2)-YEAR(A1)-IF(OR(MONTH(A2)<MONTH(A1),AND(MONTH(A2)=MONTH(A1), 
DAY(A2)<DAY(A1))),1,0)&" years, "&MONTH(A2)-MONTH(A1)+IF(AND(MONTH(A2)
<=MONTH(A1),DAY(A2)<DAY(A1)),11,IF(AND(MONTH(A2)<MONTH(A1),DAY(A2)
>=DAY(A1)),12,IF(AND(MONTH(A2)>MONTH(A1),DAY(A2)<DAY(A1)),-1)))&" months,
"&A2-DATE(YEAR(A2),MONTH(A2)-IF(DAY(A2)<DAY(A1),1,0),DAY(A1))&" days"
Notă: În cazul în care copiaţi şi lipiţi această formulă, asiguraţi-vă că nu există niciun sfârşit de linie. În cazul în care există sfârşituri de linie, formula nu va funcţiona.

4. Dacă tastaţi formula corect, celula D1 afişează:

4 years, 1 months, 6 days

Defalcarea suplimentară a formulei pentru zile, luni şi ani

Această formulă se mai poate defalca în segmente separate de zile, luni şi ani în felul următor.

Notă În cazul în care copiaţi şi lipiţi aceste formule, asiguraţi-vă că nu există nici un sfârşit de linie, altfel formulele nu vor funcţiona.

   Time segment                     Formula
   ------------------------------------------------------------------------
   The remaining number of          =A2-DATE(YEAR(A2),MONTH(A2)-
   days between two dates,          IF(DAY(A2)<DAY(A1),1,0),DAY(A1))&"days"
   ignoring years and months
   

   The remaining number of          =MONTH(A2)- MONTH(A1)+IF(AND(MONTH(A2)
   months between two dates,        <=MONTH(A1), DAY(A2)<DAY(A1)),11,
   ignoring years and days          IF(AND(MONTH(A2)<MONTH(A1),DAY(A2)>=
                                    DAY(A1)),12,IF(AND(MONTH(A2)>MONTH(A1),
                                    DAY(A2)<DAY(A1)),-1)))&" months"

   The number of whole years        =YEAR(A2)-YEAR(A1)-IF(OR(MONTH(A2)<
   between two dates                MONTH(A1),AND(MONTH(A2)=MONTH(A1),
                                    DAY(A2)<DAY(A1))),1,0)&" years"

Notă În formulele anterioare, elementele &” days”, &” months” și &” years” erau opţionale. Acestea vă permit să distingeţi rezultatele sub formă de zile, luni şi ani.

Cum se găseşte numărul de zile lucrătoare între două date

Pentru a găsi numărul de zile lucrătoare între două date, unde datele de început şi de sfârşit sunt introduse în celulele A1 şi respectiv A2, urmaţi aceşti paşi:

1. Creaţi un registru de lucru nou.
2. Faceţi clic pe Registru de lucru necompletat.
3. Tastaţi următoarele date în registrul de lucru:
A1: 03/25/94  A2: 05/01/98

4. În celula D1 tastaţi următoarea formulă:

=NETWORKDAYS(A1,A2)"1071" appears as the result in cell D1.

Cum se cresc datele în mod incremental

Pentru a creşte o dată cu un număr de ani, luni sau zile, utilizaţi formula următoare, unde reference este valoarea datei sau referinţa celulei care conţine data, iar value1value2 şi value3 sunt incrementări cu care doriţi să creşteţi anul, luna şi, respectiv, ziua.

   =DATE(YEAR(reference)+value1,MONTH(reference)+value2,DAY(reference)+value3)

De exemplu, pentru a creşte o dată cu o lună, formula este:

   =DATE(YEAR(DATEVALUE("6/20/96")),MONTH(DATEVALUE("6/20/96"))+1,
    DAY(DATEVALUE("6/20/96")))

Cum se lucrează cu formulele de timp

Cum se calculează timpul scurs

Atunci când scădeţi conţinutul unei celule din alta pentru a afla durata scursă între acestea, rezultatul este un număr de serie care reprezintă orele, minutele şi secundele scurse. Pentru ca acest număr să fie uşor de citit, utilizaţi formatul orei h:mm în celula care conţine rezultatul.

În exemplul următor, dacă celulele C2 şi D2 conţin formula =B2-A2, iar celula C2 este formatată în formatul general, celula afişează un număr zecimal (în acest caz, 0,53125, reprezentarea numărului de serie format din 12 ore şi 45 de minute).

   A1: Start Time   B1: End Time    C1: Difference  D1: Difference
                                        (General)       (h:mm)
   A2: 6:30 AM      B2: 7:15 PM     C2: 0.53125     D2: 12:45

Dacă miezul nopţii cade între ora de început şi ora de sfârşit, trebuie să ţineţi cont de diferenţa formatului de 24 de ore. Puteţi face acest lucru adăugând numărul 1, care reprezintă o perioadă de 24 de ore. De exemplu, este posibil să configuraţi următorul tabel, care permite durate dincolo de miezul nopţii.

   A1: Start Time    B1: End Time    C1: Difference  D1: Difference
                                         (General)       (h:mm)
   A2: 7:45 PM       B2: 10:30 AM    C2: 0.614583333  D2: 14:45

Pentru a configura acest tabel, tastaţi următoarea formulă în celulele C2 şi D2:

   =B2-A2+IF(A2>B2,1)

Cum se adună ore şi minute care depăşesc 24 de ore

Dacă doriţi să afişaţi corect o durată mai mare de 24 de ore, puteţi utiliza formatul încorporat 37:30:55. În schimb, dacă doriţi să utilizaţi un format particularizat, trebuie să cuprindeţi în paranteze parametrul orelor formatului, de exemplu:

   [h]:mm

Cum se face conversia unei date în numărul zecimal echivalent

Pentru a efectua conversia unei date seriale (h:mm:ss) într-un număr zecimal (0,00), trebuie să efectuaţi conversia numărului de serie într-un număr zecimal prin conversia la o bază de 24 de ore. Faceţi acest lucru înmulţind ora cu 24, după cum urmează

   =Time*24

unde Time este numărul pentru care doriţi să efectuaţi conversia dintr-un format al orei într-un număr zecimal; acest număr poate fi o referinţă de celulă sau un şir de numere al funcţiei TIMEVALUE.

De exemplu, dacă celula A1 conţine ora „4:30” pentru a reprezenta patru ore şi 30 minute, formula este:

   =A1*24

Rezultatul este 4,5.

Dacă celula conţine o dată şi o oră, utilizaţi următoarea formulă:

   =(Time-INT(Time))*24

De exemplu, dacă în celula A1 este „6/20/96 4:30 AM”, formula este:

   =(A1-INT(A1))*24

Din nou, rezultatul este 4,5.

Cum se face conversia unui număr zecimal în data echivalentă

Pentru a efectua conversia unui număr zecimal (0,00) în data serială echivalentă (h:mm:ss), trebuie să efectuaţi conversia numărului de serie într-un număr zecimal prin conversia într-o bază de 24 de ore. Faceţi acest lucru prin împărţirea orei la 24, după cum urmează

   =Time/24

unde Time este numărul pentru care doriţi să efectuaţi conversia dintr-un număr zecimal într-un număr de serie de dată şi poate fi o referinţă de celulă sau un număr real. De exemplu, dacă aveţi valoarea 4,5 pentru a reprezenta patru ore şi 30 minute, în celula A1 formula este:

   =A1/24

Rezultatul este 4:30.

Cum se transferă fişiere între Microsoft Excel pentur Mac şi Excel pentru Windows

În mod implicit, Excel pentru Mac foloseşte sistemul de dată 1904 şi Excel pentru Windows foloseşte sistemul de dată 1900. Acest lucru înseamnă că atunci când tastaţi numărul de serie 1 în Excel pentru Mac şi îl formataţi ca dată, Excel îl afişează sub forma 1/2/1904 12:00 a.m. Excel pentru Windows afişează numărul de serie 1 sub forma 1/1/1900 12:00 a.m.

Dacă transferaţi fişiere din Excel pentru Mac în Excel pentru Windows, această diferenţă a sistemelor de dată n-ar trebui să fie o problemă, deoarece sistemul datei este stocat în fiecare fişier. Cu toate acestea, în cazul în care copiaţi şi lipiţi între fişiere cu sisteme de dată diferite care îşi au originea în platforme diferite, datele se pot afişa cu o diferenţă de patru ani şi o zi faţă de data corectă.

Pentru a modifica sistemul de dată 1904 în Excel pentru Windows, urmaţi aceşti paşi:

  1. În Excel 2007 şi versiunile ulterioare, accesați Opţiuni Excel.
  2. În Excel 2007 şi versiunile ulterioare, faceţi clic pe opţiunea Complex. Defilaţi în jos până la La calcularea acestui registru de lucru: şi bifaţi caseta de selectare Se foloseşte sistemul de dată 1904.

Pentru a trece la sistemul de dată 1904 în Excel pentru Mac, urmaţi aceşti paşi:

  1. În meniul Excel, faceţi clic pe Preferinţe.
  2. La Formule şi Liste, alegeţi Calcul.
  3. La Opţiuni registru de lucru, faceţi clic pentru a debifa caseta de selectare Sistemul de dată 1904

Lasă un răspuns

Adresa ta de email nu va fi publicată. Câmpurile obligatorii sunt marcate cu *

%d blogeri au apreciat: